One of the hidden gems in DotNetNuke 5.0 is the new caching support in the CBO (Custom Business Objects) class. During the refactoring of DotNetNuke for the Cambrian release, caching was one of the things that was closely looked at, since caching was starting to cause major issues in the DNN 4.x branch.

Lets take a look at how caching was done in DNN 4:

        Public Shared Function GetSecureHostSettings() As Hashtable
            Dim h As Hashtable
            h = CType(DataCache.GetCache("GetSecureHostSettings"), Hashtable)
            If h Is Nothing Then
                h = New Hashtable
                Dim SettingName As String
                Dim dr As IDataReader = DataProvider.Instance().GetHostSettings
                While dr.Read()
                    If Not Convert.ToBoolean(dr(2)) Then
                        SettingName = dr.GetString(0)
                        If SettingName.ToLower.IndexOf("password") = -1 Then
                            If Not dr.IsDBNull(1) Then
                                h.Add(SettingName, dr.GetString(1))
                            Else
                                h.Add(SettingName, "")
                            End If
                        End If
                    End If
                End While
                dr.Close()
                DataCache.SetCache("GetSecureHostSettings", h)
            End If
            Return h
        End Function

This is code from the class DotNetNuke.Entities.Host.HostSettings in DNN 4.9.3. In fact this is a pattern that is used throughout the application in DNN 3.x – 4.x. The problem with this pattern is that it is not completely thread safe, especially if it is used in larger routines, and specifically on large and busy sites. There might be a chance that the object you get from the cache is removed from cache when you want to use it.

In DotNetNuke 5.x, the CBO class was beefed up with a new caching function:

        Public Shared Function GetCachedObject(Of TObject)(ByVal cacheItemArgs As CacheItemArgs, ByVal cacheItemExpired As CacheItemExpiredCallback) As TObject
            Return DataCache.GetCachedData(Of TObject)(cacheItemArgs, cacheItemExpired)
        End Function

which in turn calls a new method of DataCache, GetCachedData. This method looks like this:

        Public Shared Function GetCachedData(Of TObject)(ByVal cacheItemArgs As CacheItemArgs, ByVal cacheItemExpired As CacheItemExpiredCallback) As TObject
            'Declare Local Variable and try and retieve it from the cache
            Dim objObject As Object = GetCache(cacheItemArgs.CacheKey)
            Dim timeOut As Integer = cacheItemArgs.CacheTimeOut * Convert.ToInt32(Host.PerformanceSetting)

            'If Item is not cached
            If objObject Is Nothing Then

                'Prevent other threads from entering this block while we regenerate the cache
                SyncLock objLock

                    'Try to retrieve object from Cache again (in case another thread loaded the object since we first checked)
                    objObject = GetCache(cacheItemArgs.CacheKey)

                    If objObject Is Nothing Then
                        'Get Object from data Source using Delegate
                        objObject = cacheItemExpired(cacheItemArgs)

                        If objObject IsNot Nothing AndAlso timeOut > 0 Then
                            DataCache.SetCache(cacheItemArgs.CacheKey, objObject, cacheItemArgs.CacheDependency, Cache.NoAbsoluteExpiration, _
                                               TimeSpan.FromMinutes(timeOut), cacheItemArgs.CachePriority, cacheItemArgs.CacheCallback)

                            'Check if Item was actually saved in the cache
                            If DataCache.GetCache(cacheItemArgs.CacheKey) Is Nothing Then
                                Dim objEventLogInfo As New LogInfo
                                objEventLogInfo.LogTypeKey = EventLogController.EventLogType.CACHE_ERROR.ToString()
                                objEventLogInfo.LogProperties.Add(New LogDetailInfo(cacheItemArgs.CacheKey, "Not Created"))
                                Dim objEventLog As New EventLogController()
                                objEventLog.AddLog(objEventLogInfo)
                            End If
                        ElseIf objObject Is Nothing Then
                            Return Nothing
                        End If
                    End If
                End SyncLock
            End If

            Return DirectCast(objObject, TObject)
        End Function

 

As you can see, this is basically still the same pattern as the “old” pattern in DNN 3.x/4.x, however, with a few enhancements:

• Thread safety. Using Synlock, other threads are prevented to intrude when we are handling the object
• automatic callback is used, that will get called when the object is not found in cache
• check to ensure object was saved to cache correctly

As an example of the usage of the new pattern, let’s see how Host.GetSecureHostSettings was modified in DNN 5:

        Public Shared Function GetSecureHostSettingsDictionary() As Dictionary(Of String, String)
            Return CBO.GetCachedObject(Of Dictionary(Of String, String))(New CacheItemArgs(DataCache.SecureHostSettingsCacheKey, _
                                                                                               DataCache.HostSettingsCacheTimeOut, _
                                                                                               DataCache.HostSettingsCachePriority), _
                                                                                               AddressOf GetSecureHostSettingsDictionaryCallBack)
        End Function

And the corresponding callback function:

        Private Shared Function GetSecureHostSettingsDictionaryCallBack(ByVal cacheItemArgs As CacheItemArgs) As Object
            Dim dicSettings As New Dictionary(Of String, String)

            Dim dr As IDataReader = DataProvider.Instance().GetHostSettings
            Try
                While dr.Read()
                    If Not Convert.ToBoolean(dr(2)) Then
                        Dim settingName As String = dr.GetString(0)
                        If settingName.ToLower.IndexOf("password") = -1 Then
                            If Not dr.IsDBNull(1) Then
                                dicSettings.Add(settingName, dr.GetString(1))
                            Else
                                dicSettings.Add(settingName, "")
                            End If
                        End If
                    End If
                End While
            Finally
                If Not dr Is Nothing Then
                    dr.Close()
                End If
            End Try

            Return dicSettings
        End Function

As you can see, the callback function GetSecureHostSettingsDictionaryCallBack is essentially the same as the old method, minus the caching logic. It has become far more easier to use caching in your own module using this pattern. A few lines of code will do the trick.